| 12345678910111213141516171819202122232425262728293031323334353637383940414243444546474849505152535455565758596061626364656667 |
- # Copyright 1999-2017 Gentoo Foundation
- # Distributed under the terms of the GNU General Public License v2
- EAPI=6
- inherit autotools multilib eutils
- MY_PN="ZenLib"
- DESCRIPTION="Shared library for libmediainfo and mediainfo"
- HOMEPAGE="https://github.com/MediaArea/ZenLib http://mediaarea.net/mediainfo/"
- SRC_URI="http://mediaarea.net/download/source/${PN}/${PV}/${P/-/_}.tar.bz2"
- LICENSE="ZLIB"
- SLOT="0"
- KEYWORDS="~amd64 ~x86"
- IUSE="doc static-libs"
- DEPEND="virtual/pkgconfig
- doc? ( app-doc/doxygen )"
- S=${WORKDIR}/${MY_PN}/Project/GNU/Library
- src_prepare() {
- default
- sed -i 's:-O2::' configure.ac || die
- eautoreconf
- }
- src_configure() {
- econf \
- --enable-unicode \
- --enable-shared \
- $(use_enable static-libs static)
- }
- src_compile() {
- default
- if use doc ; then
- cd "${WORKDIR}"/${MY_PN}/Source/Doc
- doxygen Doxyfile || die
- fi
- }
- src_install() {
- default
- # remove since the pkgconfig file should be used instead
- rm "${D}"/usr/bin/libzen-config
- insinto /usr/$(get_libdir)/pkgconfig
- doins ${PN}.pc
- for x in ./ Format/Html Format/Http HTTP_Client ; do
- insinto /usr/include/${MY_PN}/${x}
- doins "${WORKDIR}"/${MY_PN}/Source/${MY_PN}/${x}/*.h
- done
- dodoc "${WORKDIR}"/${MY_PN}/History.txt
- if use doc ; then
- docinto html
- dodoc "${WORKDIR}"/${MY_PN}/Doc/*
- fi
- prune_libtool_files
- }
|
